Programowanie: Detekcja stereo
From Atariki
(Różnice między wersjami)
| Wersja z dnia 11:53, 30 kwi 2010 Mono (Dyskusja | wkład) (detekcja stereo zaproponowana przez sebana) ← Previous diff |
Wersja z dnia 11:55, 30 kwi 2010 Mono (Dyskusja | wkład) (kategorie) Next diff → |
||
| Linia 38: | Linia 38: | ||
| rts ; exit | rts ; exit | ||
| </pre> | </pre> | ||
| + | |||
| + | [[Kategoria:Programowanie Atari 8-bit]] | ||
| + | [[Kategoria:Niezbędnik kodera]] | ||
Wersja z dnia 11:55, 30 kwi 2010
Metoda zaproponowana w wątku Detekcja STEREO - tester przez Sebana/SLIGHT polega na założeniu, że drugi POKEY podłączony w obszarze $D210..$D21F nie ma podłączonych przerwań IRQ. Próba uaktywnienia przerwania licznika 1 drugiego POKEYa nie powinna wygenerować przerwania IRQ. Jeśli przerwanie jednak wystąpiło, można założyć że rozszerzenie nie jest obecne i adresowanie jego obszaru zainicjalizowało w rzeczywistości przerwanie IRQ licznika 1 standardowego POKEYa znajdującego się w obszarze $D200..$D20F (jest to konsekwencją uproszczonej budowy dekodera adresów).
* -----------------------------
* |second POKEY detect routine|
* | answer in A register: |
* |$00 - absent $80 - present |
* -----------------------------
* | code & idea: Seban/SLIGHT |
* |-+* (c) 1995,96 Slight! *+-|
* -----------------------------
st sei ; disable IRQ
inc $d40e ; disable NMI
lda #$03 ; A reg=3
sta $d21f ; init POKEY
sta $d210 ; set freq of channel #1 (timer #1)
ldx #$00 ; X reg=0
stx $d211 ; set volume of channel #1 to zero
inx ; X reg=1
stx $d21e ; enable TIMER1 IRQ
ldx $d40b ; wait for scan line #0
bne *-3
stx $d219 ; start POKEY TIMERS
w ldx $d40b ; check current scan line
bmi ext ; when >=128 and no IRQ is present second POKEY detected! EXIT!
lda #$01 ; check POKEY TIMER1 IRQ status
bit $d20e
bne w ; when no IRQ is present... loopback!
; if IRQ is present, it means no second pokey detected!
; X reg have zero value
ext lda $10 ; restore IRQ mask
sta $d20e
dec $d40e ; enable NMI
cli ; enable IRQ
txa ; X to A
rts ; exit
