Dostęp do plików

From Atariki

Jak napisano w haśle CIO, z dostępem do plików związane są w Atari tak zwane bloki kontroli wejścia i wyjścia (ang. Input/Output Control Blocks, albo IOCB). Jest ich osiem, każdy liczy 16 bajtów, ulokowane są w pamięci RAM, w obszarze od $0340 do $03BF. Ich struktura opisana jest w wyżej wymienionym haśle CIO, opis ten tutaj zostanie zatem pominięty. Wystarczy napisać, że block IOCB służy do zdefiniowania operacji na pliku i nadaniu jej parametrów wejściowych a także - odebraniu wyników (na ogół: kodu statusu).

Spis treści 1 Adresowanie IOCB 2 Etykiety IOCB 3 Funkcje IOCB 4 Otwarcie pliku = 5 Zamknięcie pliku 6 Odczyt danych z pliku 6.1 Odczyt bloku danych binarnych 6.2 Odczyt pojedynczego bajtu 6.3 Odczyt rekordu tekstowego 7 Zapis do pliku 7.1 Zapis bloku danych binarnych 7.2 Zapis pojedynczego bajtu 7.3 Zapis rekordu

Adresowanie IOCB

Bloki IOCB konwencjonalnie adresuje się podając adres wewnątrz pierwszego z nich - czyli $034x - jako argument rozkazu w trybie absolutnym indeksowanym X, przy czym w rejestrze X powinien znajdować się numer bloku IOCB (z zakresu od 0 do 7), pomnożony przez 16. Numer kanału IOCB, pełniący rolę uchwytu (ang. handle) pliku, powinien zostać właśnie w tej postaci, i w tym rejestrze, przekazany do głównej procedury CIO (CIOV lub JCIOMAIN, $E456) przy jej wywoływaniu.

Etykiety IOCB

icchid = $0340
icdno  = $0341
iccmd  = $0342
icstat = $0343
icbufa = $0344
icputb = $0346
icbufl = $0348
icax1  = $034a
icax2  = $034b
icax3  = $034c
icax4  = $034d
icax5  = $034e
icax6  = $034f

Z całego bloku dla omawianego tu zagadnienia istotne są:

• ICCMD - zapisuje się w nim jeden bajt symbolizujący rodzaj operacji (OPEN, CLOSE itd.)
• ICBUFA - to adres bufora
• ICBUFL - to wielkośc bufora w bajtach
• ICAX1/2 - to bajty pomocnicze, zawierające różne dodatkowe parametry

Czasem przydaje się też ICSTAT, po zakończeniu operacji zawiera bowiem jej status (czyli $01 albo kod błędu). Ale rzadko się tę wartość odczytuje stamtąd, bo przekazywana jest też przez OS bezpośrednio w rejestrze Y.

Reszty bajtów IOCB nie dotykamy i w ogóle (na ogół) nie zawracamy sobie nimi głowy.

Funkcje IOCB

W teorii wszystkie bloki mają to samo przeznaczenie: każdy służy jako deskryptor pojedynczego, otwartego pliku. Wynika z tego, że w teorii można otworzyć do ośmiu plików na raz. W praktyce jeden blok - IOCB #$00 - jest defaultowo otwarty dla edytora ekranowego. Można go wprawdzie zamknąć i wykorzystać do czegoś innego, ale nie ma potrzeby tego czynić, gdyż w praktyce przeciętny DOS nie pozwoli otworzyć więcej niż 3-4 pliki na raz.

Pierwszy wolny IOCB to IOCB #1, i ten właśnie będzie używany w przykładach.

Otwarcie pliku =

W Atari można otworzyć plik dyskowy do odczytu, zapisu, wymiany danych (naprzemiennego odczytu i zapisu) oraz dopisywania. Ogólne zasady są takie, jak wszędzie indziej, to znaczy:

• plik otwierany do odczytu musi istnieć, w przeciwnym wypadku wystąpi błąd 170 (FILE NOT FOUND);
• plik otwierany do zapisu, jeśli nie istnieje, zostanie utworzony, natomiast jeśli istnieje, jego dotychczasowa zawartość zostanie skasowana;
• plik otwierany do odczytu i zapisu, jeśli istnieje, zostanie otwarty, natomiast jeśli nie istnieje, zostanie utworzony;
• plik otwierany do dopisywania jeśli istnieje, zostanie otwarty, a wskaźnik miejsca, do któego trafią zapisywane dane, zostanie ustawiny na jego końcu; jeśli zaś taki plik nie istnieje, zostanie utworzony.

Kod:

 ciov = $e456
 
 fname .byte "D:FOOBAR12.DAT",$9b
 
 open_file
       ldx #$10            ;IOCB #1
       lda #$03            ;komenda: OPEN
       sta iccmd,x
       lda #<fname         ;adres nazwy pliku
       sta icbufa,x
       lda #>fname
       sta icbufa+1,x
       lda #$xx            ;kod dostępu: $04 odczyt, $08 zapis, $09 dopisywanie, $0c odczyt/zapis, $0d odczyt/dopisywanie
       sta icax1,x
       lda #$00            ;dodatkowy parametr, zawsze $00
       sta icax2,x 
       jsr ciov

Nazwa pliku musi spełniać następujące warunki:

• na początku musi się znajdować specyfikacja urządzenia, na ogół będzie to "D:", co oznacza stację dysków (a ściślej: DOS). Można tu podać numer stacji, np. "D2:", jednak najlepiej poprzestać na "D:" - pozwala to bardziej zaawansowanym DOS-om na zapis tego pliku do bieżącego podkatalogu, czyli na ogół tego, w którym uzytkownik trzyma cały program.

• za dwukropkiem podajemy nazwę pliku w konwencji "8.3", tj. składającą się z najwyżej ośmiu znaków nazwę właściwą, kropkę oraz liczące do trzech znaków rozszerzenie. Znakami dopuszczalnymi w nazwie są duże litery alfabetu angielskiego (A-Z), cyfry (0-9) oraz znak podkreślenia. Cześć DOS-ów wymaga, żeby pierwszym znakiem nazwy była litera.

• za ostatnim znakiem nazwy pliku obowiązkowo powinien się znaleźć znak jej końca, czyli EOL (znak Return, ASCII $9B).

Po wywołaniu JSR OPEN_FILE w rejestrze X będzie się znajdował (nadal) numer kanału pomnożony przez 16, a w rejestrze Y kod statusu, natomiast bit N rejstru znaczników będzie odzwierciedlał stan rejestru Y: jeśli N=1, to znaczy, że wystąpił błąd o kodzie przekazanym w Y. W przeciwnim wypadku (N=0) operacja się powiodła.

UWAGA: specyfiką Atari jest to, że po każdym OPEN, nawet jeśli zakończyło się błędem, kanał IOCB pozostaje otwarty i trzeba go zamknąć do ponownego użycia. Zakonczenie programu nie powoduje automatycznego zamknięcia otwartych kanałów.

Zamknięcie pliku

Jedynym parametrem wymaganym tutaj jest numer kanału IOCB pomnożony przez 16, czyli "uchwyt pliku". Kod:

 ciov = $e456
 
 close_file
       ldx #$10            ;IOCB #1
       lda #$0c            ;komenda: CLOSE
       sta iccmd,x
       jsr ciov

Odczyt danych z pliku

Plik otwarty do odczytu będzie czytany sekwencyjnie od początku do końca. Jeśli nie wystąpią żadne błędy, i odczytano wszystkie dane z pliku, następna próba odczytu zwróci błąd nr 136 (EOF). Ważne jest, żeby status operacji testować na okoliczność wystąpienia błędu (N=1, Y>127), a nie na okoliczność powodzenia (Y=$01), gdyż część DOS-ów w pewnych warunkach zwraca wartość $03 jako status dla udanej operacji odczytu.

Odczyt bloku danych binarnych

Kod:

 ciov = $e456
 
 read_binary
       ldx #$10            ;IOCB #1
       lda #$07            ;komenda: GET BYTES / BINARY READ
       sta iccmd,x
       lda #<buffer        ;adres w pamieci, gdzie maja trafic dane
       sta icbufa,x
       lda #>buffer
       sta icbufa+1,x
       lda #<buflen        ;wielkosc bloku danych w bajtach
       sta icbufl,x
       lda #>buflen
       sta icbufl+1,x
       jsr ciov

Odczyt pojedynczego bajtu

Do odczytania pojedynczego bajtu nie potrzeba deklarować bufora: jeśli zadeklarujemy zerową wielkość bufora, system odczyta 1 bajt i przekaże go w akumulatorze:

 ciov = $e456
 
 read_one_byte
       ldx #$10            ;IOCB #1
       lda #$07            ;komenda: GET BYTES / BINARY READ
       sta iccmd,x
       lda #$00
       sta icbufl,x
       sta icbufl+1,x
       jsr ciov

Odczyt rekordu tekstowego

Rekord tekstowy jest to ciąg znaków ATASCII zakończony znakiem Return (EOL, ASCII $9B). Rekord musi mieścić się w zadeklarowanym buforze, jeśli bufor zapełni się zanim odczytany zostanie znak EOL, wystąpi błąd 137 (TRUNCATED RECORD).

Kod jest prawie taki sam, jak w przypadku danych binarnych, różni się tylko kodem operacji:

 ciov = $e456
 
 read_text
       ldx #$10            ;IOCB #1
       lda #$05            ;komenda: GET RECORD
       sta iccmd,x
       lda #<buffer        ;adres w pamieci, gdzie maja trafic dane
       sta icbufa,x
       lda #>buffer
       sta icbufa+1,x
       lda #<buflen        ;wielkosc rekordu w bajtach
       sta icbufl,x
       lda #>buflen
       sta icbufl+1,x
       jsr ciov

Zapis do pliku

Zapis przeprowadza się analogicznie do odczytu, może się jedynie zmieniać miejsce, gdzie dane zostaną zapisane. Jest to zależne od trybu otwarcia pliku: przy zwykłym zapisie (tryb otwarcia 8) lub wymianie danych (tryb otwarcia 12) dane będą wpisywane do pliku sekwencyjnie od początku. Przy dopisywaniu (tryb 9) lub odczycie/dopisywaniu (tryb 13) wpisane do pliku dane znajdą się na jego końcu.

Zapis bloku danych binarnych

 ciov = $e456
 
 write_binary
       ldx #$10            ;IOCB #1
       lda #$0b            ;komenda: PUT BYTES / BINARY WRITE
       sta iccmd,x
       lda #<buffer        ;adres w pamieci, gdzie znajduja sie dane
       sta icbufa,x
       lda #>buffer
       sta icbufa+1,x
       lda #<buflen        ;wielkosc bloku danych w bajtach
       sta icbufl,x
       lda #>buflen
       sta icbufl+1,x
       jsr ciov

Zapis pojedynczego bajtu

Analogicznie jak przy odczycie, zdefiniowanie zerowej wielkości bufora spowoduje, że do pliku zostanie zapisana zawartość akumulatora:

 ciov = $e456
 
 write_one_byte
       pha
       ldx #$10            ;IOCB #1
       lda #$0b            ;komenda: PUT BYTES / WRITE BINARY
       sta iccmd,x
       lda #$00
       sta icbufl,x
       sta icbufl+1,x
       pla
       jsr ciov

Zapis rekordu

Na końcu bufora danych powinien się znajdować znak EOL (ASCII $9B). Zadeklarowana wielkość bufora powinna być większa lub równa liczbie zapisywanych danych. Kod:

 ciov = $e456
 
 write_text
       ldx #$10            ;IOCB #1
       lda #$09            ;komenda: PUT RECORD
       sta iccmd,x
       lda #<buffer        ;adres w pamieci, skad maja byc pobrane dane
       sta icbufa,x
       lda #>buffer
       sta icbufa+1,x
       lda #<buflen        ;wielkosc rekordu w bajtach
       sta icbufl,x
       lda #>buflen
       sta icbufl+1,x
       jsr ciov