Tekst źródłowy strony Ustawianie i kasowanie znaczników

Gdy w programie zachodzi potrzeba zastosowania globalnego, dwustanowego znacznika (tzw. flagi), najwygodniej jest w tym celu użyć bitów 7 lub 0 komórki pamięci:

== Bit 7 ==
Bit 7 komórki pamięci, gdy pozostała jej zawartość nie ma dla programu znaczenia, można ustawić rozkazem ROR. Zamiast:
<pre>
    lda #$80
    sta znacznik
</pre>
można zaoszczędzić 1 bajt programu w ten sposób:
<pre>
    sec
    ror znacznik
</pre>
Analogicznie, do skasowania bitu 7 mozna użyć rozkazu LSR. Zamiast:
<pre>
    lda #$00
    sta znacznik
</pre>
piszemy:
<pre>
    lsr znacznik
</pre>
oszczędzając dwa bajty. Dodatkową korzyścią jest ustalenie stanu bitu N rejestru znaczników procesora (zawsze skasowany po LSR), tak więc gdy zachodzi potem potrzeba wykonania krótkiego skoku bezwarunkowego, można użyć BPL. Zamiast:
<pre>
    lsr argument
    jmp adres
</pre>
można użyć:
<pre>
    lsr argument
    bpl adres
</pre>
Gdy chcemy skasować bit 7 komórki pamięci nie naruszając stanu pozostałych jej bitów, zamiast:
<pre>
    lda znaczniki
    and #$7f
    sta znaczniki
</pre>
oszczędzamy dwa bajty pisząc:
<pre>
    asl znaczniki
    lsr znaczniki
</pre>
Sprawdzenie stanu takiego znacznika robi się rozkazem BIT lub LDA/LDX/LDy i odgałęzieniem BPL/BMI zależnie od potrzeb. Zamiast:
<pre>
    lda znacznik
    and #$80
    bne ustawiony
</pre>
piszemy:
<pre>
    bit znacznik
    bmi ustawiony
</pre>
Sprawdzenie z automatycznym skasowaniem (jeśli pozostałe bity bajtu mają wartość 0), zamiast:
<pre>
    lda znacznik
    bpl skasowany
    and #$7f
    sta znacznik
    ...
</pre>
możemy napisać:
<pre>
    asl znacznik
    bcc skasowany
</pre>

== Bit 0 ==
Ustawianie i kasowanie bitu 0 robi się analogicznie jak wyżej opisano z bitem 7. Ustawienie:
<pre>
    sec
    rol znacznik
</pre>
Skasowanie, gdy pozostałe bity nie mają znaczenia:
<pre>
    asl znacznik
</pre>
albo, gdy mają:
<pre>
    lsr znaczniki
    asl znaczniki
</pre>
Sprawdzenie stanu z automatycznym skasowaniem (warunek jak powyżej):
<pre>
    lsr znacznik
    bcs ustawiony
</pre>
Sprawdzenie stanu bez skasowania, zamiast:
<pre>
    lda znacznik
    and #$01
    bne ustawiony
</pre>
oszczędzamy 1 bajt:
<pre>
    lda znacznik
    lsr
    bcs ustawiony
</pre>

[[Kategoria:Niezbędnik kodera]]