Programowanie: Jak parsować przełączniki z parametrami

SpartaDOS X pozwala na przekazywanie parametrów w wywołaniu programu. Mogą one być parsowane za pomocą procedur wspomnianych w 5 rozdziale podręcznika programowania traktującym o obróbce wiersza poleceń.

Procedura U_SLASH pozwala na wygodne parsowanie serii przełączników wyliczonych po sobie, a nie rozdzielonych innymi parametrami. Przykładowo parsowanie linii poleceń w wywołaniu:

 A:> MYPRG /X /A 23 /Q

wymaga użycia kolejno:

• U_SLASH dla /X i /A naraz
• U_GETNUM dla 23
• U_SLASH dla /Q

a nie, jak intuicyjnie mogłoby się wydawać:

• U_SLASH dla /X
• U_SLASH dla /A
• U_GETNUM dla 23
• U_SLASH dla /Q

Ponieważ kolejność przełączników nie ma dla procedury U_SLASH znaczenia, to wynik jej działania będzie identyczny również dla:

 A:> MYPRG /A /X 23 /Q
 A:> MYPRG /XA 23 /Q
 A:> MYPRG /AX 23 /Q

jak również (pominąwszy fakt zliczania przez SDX począwszy od wersji 4.47 ilości wystąpień przełączników o tej samej nazwie) dla:

 A:> MYPRG /AAA /XX 23 /Q
 A:> MYPRG /XXAAA 23 /Q
 A:> MYPRG /AAAXX 23 /Q
 A:> MYPRG /AXAXA 23 /Q

Jeśli jednak przełącznik /A miałby występować łącznie z parametrem liczbowym, wtedy okaże się, że wywołania:

 A:> MYPRG /X /A 23 /Q
 A:> MYPRG /A /X 23 /Q
 A:> MYPRG /XA 23 /Q
 A:> MYPRG /AX 23 /Q

będą dla U_SLASH nierozróżnialne właśnie dlatego, że przełączniki /A i /X następujące po sobie są obsługiwane przez jedno jej wywołanie.

Dodatkową trudnością jest też fakt, że dla minimum trzech różnych przełączników następujących bezpośrednio po sobie nie można też określić ich kolejności. Można natomiast ustalić jaki przełącznik wystąpił ostatnio - dokonuje tego procedura:

getlastswitch:
  ldy BUFOFF
@:dey
  lda LBUF,y
  cmp #' '
  beq @-
  cmp #','
  beq @-
  rts

zwracająca w akumulatorze kod ATASCII przełącznika.

Przykładowa procedura parsująca przełączniki /A (z parametrem), /X i /Q może wyglądać tak:

parseswitches:
  lda swad
  ldx swad+1
  lda #swlen
  jsr U_SLASH
  sec
  lda swa
  beq @+
  jsr proca
@:lda swq
  beq @+
  jsr procq
@:lda swx
  beq @+
  jsr procx
@:bcc parseswitches
  ; nie wykryto żadnych przełączników
  rts
sw:
swa .db 0,'A'
swq .db 0,'Q'
swx .db 0,'X'
swlen = *-sw
swad .dw sw

proca:
  jsr getlastswitch
  cmp swa+1
  bne error  ;parametr liczbowy ma następować zaraz po /A 
  jsr U_GETNUM
  beq error  ;parametr po /A nie jest liczbą
  ...
  clc        ;informacja że przetworzyliśmy przełącznik
  rts

procq:
  ...
  clc
  rts

procx:
  ...
  clc
  rts

error:
  lda #kod_błędu
  jmp U_FAIL

Procedura poprawnie obsługuje przełączniki bez względu na kolejność ich wystąpienia, więc wywołania:

 A:> MYPRG /X /A 23 /Q
 A:> MYPRG /XA 23 /Q
 A:> MYPRG /XXAAA 23 /Q
 A:> MYPRG /AXAXA 23 /Q

zostaną poprawnie przeparsowane, natomiast:

 A:> MYPRG /A /X 23 /Q
 A:> MYPRG /AX 23 /Q
 A:> MYPRG /AAA /XX 23 /Q
 A:> MYPRG /AAAXX 23 /Q

zakończą się błędem.

Uwagi

Procedura U_SLASH począwszy od SDX 4.47 zwraca w akumulatorze kod ATASCII ostatnio napotkanego przełącznika.